[Contents] [Prev] [Next] [Index] [Report an Error]

Warning About a Deprecated Value

In previous versions of the JUNOS software, you could include the speed statement at the [edit system ports console] hierarchy level with a speed setting lower than 9600 baud. Since Release 7.4, setting the speed lower than 9600 baud has been deprecated.

For general information about deprecated configuration statements, see the JUNOS Release Notes.

This example allows you to set the speed statement at the [edit system ports console] hierarchy level, but the commit script produces an error message if you set the speed lower than 9600 baud.

XSLT Syntax



<?xml version="1.0" standalone="yes"?>


<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:junos="http://xml.juniper.net/junos/*/junos"
    xmlns:xnm="http://xml.juniper.net/xnm/1.1/xnm"
    xmlns:jcs="http://xml.juniper.net/junos/commit-scripts/1.0">


    <xsl:import href="../import/junos.xsl"/>


    <xsl:template match="configuration">
        <xsl:if test="system/ports/console/undocumented/speed &lt; 9600">
            <xnm:warning>
                <xsl:call-template name="jcs:edit-path">
                    <xsl:with-param name="dot" select="system/ports/console"/>
                </xsl:call-template>
                <xsl:call-template name="jcs:statement">
                    <xsl:with-param name="dot"                                    select="system/ports/console/undocumented/speed"/>
                </xsl:call-template>
                <message>
                    <xsl:text>Console speeds less than</xsl:text>
                    <xsl:text>9600 baud are deprecated.</xsl:text>
                </message>
            </xnm:warning>
            <change>
                <system>
                    <ports>
                        <console>
                            <speed delete="delete"/>
                        </console>
                    </ports>
                </system>
            </change>
        </xsl:if>
    </xsl:template>


</xsl:stylesheet>

SLAX Syntax



version 1.0;


ns junos = "http://xml.juniper.net/junos/*/junos";
ns xnm = "http://xml.juniper.net/xnm/1.1/xnm";
ns jcs = "http://xml.juniper.net/junos/commit-scripts/1.0";


import "../import/junos.xsl";
match configuration {
    if (system/ports/console/undocumented/speed < 9600) {
        <xnm:warning> {
            call jcs:edit-path($dot = system/ports/console);
            call jcs:statement($dot = system/ports/console/undocumented/speed);
            <message> {
                expr "Console speeds less than";
                expr "9600 baud are deprecated.";
            }
        }
        <change> {
            <system> {
                <ports> {
                    <console> {
                        speed delete="delete">;
                    }
                }
            }
        }
    }
}

Testing ex-deprecated.xsl

To test the example in this section, perform the following steps:

From Warning About a Deprecated Value, copy the Extensible Stylesheet Language Transformations (XSLT) or SLAX script into a text file, and name the file ex-deprecated.xsl. Copy the ex-deprecated.xsl file to the /var/db/scripts/commit directory on your routing platform.
Select the following configuration, and press Ctrl+c to copy it to the clipboard. If you are using the SLAX version of the script, change the filename to filename.slax.system { ports { console speed 4800; } scripts { commit { file ex-deprecated.xsl; } } }
Merge the configuration into your routing platform configuration by issuing the load merge terminal configuration mode command:[edit] user@host# load merge terminal [Type ^D at a new line to end input] > Paste the contents of the clipboard here<
1. At the prompt, paste the contents of the clipboard using the mouse and the paste icon.
2. Press Enter.
3. Press Ctrl+d.

Issue the commit command. When you issue the commit command, the following output appears:



[edit]
user@host# commit

[edit system ports console]
    'speed 4800;'
    warning: Console speeds less than 9600 baud are deprecated.
commit complete

[Contents] [Prev] [Next] [Index] [Report an Error]